Le portail francophone de la géomatique

commande :  _ADESETCRDSYS     sous AutoCAD MAP (Menu MAP -> Outils -> attribuer un système de coordonnée)

Bonjour,

Est-il possible de connaitre le le système de projection d'un fichier .dwg ouvert avec Autocad Map? Est-ce écrit quelque part dans le fichier? La commande  _ADESETCRDSYS  permet seulement de changer de système, pas de connaitre cette information il me semble.

Merci d'avance. JML

Bonjour,

Est-il possible de connaitre le le système de projection d'un fichier .dwg ouvert avec Autocad Map?

Oui, avec une fonction lisp de map. Dans la ligne de commande, tapez simplement (ade_projgetwscode)

Si ça peut intéresser quelqu'un, un petit bout de code qui permet d'obtenir les coordonnées d'un point dans un autre système de projection que celui défini dans le dessin sans changer le système de projection avec _ADESETCRDSYS.

Par exemple pour passer du Lambert RGF93 au Lambert II Etendue

(defun c:xy_RGF932LIIE (/ as_cor ll lat lon pkpt desc)
    (setq as_cor (ade_projgetwscode))
    (if (/= "" as_cor)
        (progn
            (ade_projsetsrc as_cor)
            (ade_projsetdest "NTF.Lambert-E")
            (while (not (setq pkpt (getpoint "\nDonnez le point désiré: "))))
            (setq
                ll (ade_projptforward pKpt)
                lat (car ll)
                lon (car (cdr ll))
                desc (ade_projgetinfo "NTF.Lambert-E" "description")
            )
            (princ 
                (strcat
                    "X: " (rtos lat 2 6)
                    "\nY:" (rtos lon 2 6)
                    "\n Converti depuis: " as_cor
                    "\n Converti vers  : " desc
                )
            )
            (princ)
        )
        (asg_coor)
    )
)
(defun asg_coor (/ req )
    (initget "Oui Non _Yes No" )
    (setq req (getkword "Pas de coordonnées assignées à cette carte, Voulez l'assigner maintenant? [Oui/Non]? <Non>: "))
    (if (= nil req) (setq req "Yes"))
    (if (= req "Yes")
        (progn
            (command "ADESETCRDSYS")
            (if (/= "" (ade_projgetwscode))
                (C:xy_RGF932LIIE)
                (Alert "\nEchec d'attribution de système de coordonnées")
            )
        )
        (princ "\nAu revoir")
    )
    (princ)
)

Bonjour,

jomoluan a écrit:

La commande  _ADESETCRDSYS  permet seulement de changer de système, pas de connaitre cette information il me semble.

C'est pourtant le cas : si un système de projection est défini dans le DWG, _ADESETCRDSYS permet bien de le modifier, mais permet aussi de le connaitre.

Patrice a écrit:

Superbe, je ne savais pas que l'on pouvait faire de la reprojection "ponctuelle" dans MAP (ou CIVIL) !

Pour information, on peut aussi le faire dans le "Suivi des coordonnées" (commande MapTrackCS) - voir image ci-jointe.

Cordialement,
Gwenael Bachelot
Autodesk