Le portail francophone de la géomatique

L'angle est bien entendu indépendant de l'échelle (il ne sont pas liés mathématiquement). Toutefois, avec le calcul matriciel classique, ce n'est pas l'angle "a" qu'on détermine directement, mais les valeurs C=k*cos a et D=k*sin a.
On calcule ensuite :
a = atan (D/C)
k = racine(C²+D²)
On n'arrive donc pas à fixer une valeur pour k, en l'occurence 1.
Sur le lien donné est étudié une transformation de Helmert avec facteur d'échelle. Ce n'est donc pas ce que je cherche.

Justement, le souci est qu'après le calcul par les moindres carrés, on a C²+D² différent de 1.

Bonjour,
Effectivement, c'est astucieux, et celà fonctionne.
J'ai eu un peu de mal à trouver la matrice pour :

X = X' -Y' da +dTx
Y = X' da + Y'+dTy

En fait il faut partir de :

X-X' = -Y' da +dTx
Y-Y' = X' da +dTy

Sur les exemples essayés, da est négligeable (environ 1E-12 grades).
Merci

Bonjour,

Ci-joint le fichier tableur avec un exemple (format ods libreoffice/openoffice).

L'inconvénient du calcul avec tableur c'est qu'il faut réajuster toutes les formules de calcul matriciel lorsque le nombre de coordonnées change.

Il y a peu j'ai découvert Scilab, un programme de calcul assez pratique à utiliser ( http://www.scilab.org/fr ). Voici donc le script scilab correspondant. Il suffit de rentrer les coordonnées de départ et d'arrivée au début, et le reste est fait automatiquement.

A bientôt

//SCILAB
printf("\nCalcul des Paramètres d''une Transformation Helmert en 2D avec f=1\n")
printf("-----------------------------------------------------------------\n")
//Coordonnées de départ :
DEPART=[
10 10
12 10
11 12
];
disp(DEPART,"Coordonnées de départ :")
//Coordonnées d'arrivée :
ARRIVEE=[
15 10
17.2 9.7
16.1 12.5
];
disp(ARRIVEE,"Coordonnées d''arrivée :")
printf("\nTransformation avec facteur d''echelle :\n")
A=matrix(ARRIVEE',-1,1);
M=[1 -1 1 0
1 1 0 1];
N=matrix(cat(2,DEPART,flipdim(DEPART,2))',2,-1)';
B=cat(2,N,ones(N)).*repmat(M,size(DEPART,1),1);
P=lsq(B,A);
rotation=atan(P(2,1)/P(1,1));
printf("\tRotation = %.5f grades\n",rotation*200/%pi)
printf("\tf = %.6f\n",sqrt(P(2,1)^2+P(1,1)^2))
printf("\tTx = %.3f m\n",P(3,1))
printf("\tTy = %.3f m\n\n",P(4,1))
RESIDUS=B*P-A
printf("\nTransformation sans facteur d''echelle :\n")
P2=[cos(rotation);sin(rotation);P(3:4,1)];
A3=B*P2;
A4=A-A3;
M=[-1 1 0
1 0 1];
N=matrix(flipdim(matrix(A3,2,-1),1),-1,1);
B3=cat(2,N,ones(size(N,1),2)).*repmat(M,size(DEPART,1),1);
P3=lsq(B3,A4);
PARAMETRES=(P3+[rotation;P(3:4,1)]);
printf("\tRotation = %.5f grades\n",PARAMETRES(1,1)*200/%pi)
printf("\tTx = %.3f m\n",PARAMETRES(2,1))
printf("\tTy = %.3f m\n\n",PARAMETRES(3,1))
RESIDUS=A3+B3*P3-A
//quit()

j'ai trouvé ...

  J'ai trouvé une feuille de calcul qui prend un nombre indéterminé de point (donc semble avoir résolue le problème de la taille des matrices).
Elle provient de :http://www.google.fr/url?sa=t&rct=j … Oa1RQjAHGg (en anglais).
Dans ce fichier excel, bien réalisé il me semble, il y a :
-> la transfo helmert 2D (avec mise à l'échelle)
-> la transfo helmert 3D (avec mise à l'échelle) qui ne se charge pas bien sous Open Office (des modif sont a faire pour retrouver les formules).
-> et aussi, en bonus (premier onglet) une transfo "affine" (?) où l'on peut pondéré les points de calage.

  Toute ces transfos sont de plus réversible (on peut re-transformer un point levé dans le système de départs via les même paramètre).
C'est typiquement ce qu'il me faudrait comme utilitaire mais avec le calcul sans mise à l’échelle.

J'y ai rajouté la solution de PierreBrial en bidouillant au petit bonheur la chance .

Je pense que ce fichier peu servir a bon nombre d'entre nous.

Merci a vous.

Dernière modification par pelouab (jeu. 01 novembre 2012 21:36)