Le portail francophone de la géomatique

calito · Mon 09 June 2008 23:58

Bonjour,

J'ai réaliser un p'tit programme qui me permet de passer des requêtes par attribut sur une couche, Je n'sais pas comment utiliser 'query deff' en VBA pour que je puisse voir seulement les entitées sélectionnées sur la carte.

Merci pour votre aide.

Tnarbiv · Tue 10 June 2008 09:05

Bonjour,

peut être que cela pourra t'aider :

Code:

' Get a reference to the first layer in the map
Dim pMxDoc As IMxDocument
Set pMxDoc = ThisDocument
Dim pMap As IMap
Set pMap = pMxDoc.FocusMap
Dim pFLayer As IFeatureLayer
Set pFLayer = pMap.Layer(0)
' Set the definition query of the layer
Dim pFLDef As IFeatureLayerDefinition
Set pFLDef = pFLayer
' QI from the FeatureLayer
pFLDef.DefinitionExpression = "SUB_REGION = 'Pacific'"
' set the definition expression
pMxDoc.ActiveView.Refresh

Je pense qu'il ne te reste plus qu'à mettre ta requête attributaire à la place de "SUB_REGION = 'Pacific'"

Dernière modification par Tnarbiv (Tue 10 June 2008 09:06)

calito · Wed 11 June 2008 12:11

Merci infiniment, c'est correct.
J'ai deux question:
1- Est-ce que vous pouvez me fournir un lien ou un doc numerique qui explique tres tres bien le modele ArcObjet (les schemas)?

2- J'ai fait une petite application dans laquelle j'ai passe une requête, et que j'aimerais changer la couleur des entités sélectionnées, je n'arrive pas à le faire. j'ai toujour cette erreur:Invalde use property (j'ai mal utilisé la propriété).

Voici le code:

Dim Doc As IMxDocument
Set Doc = ThisDocument
Dim mMap As IMap
Set mMap = Doc.FocusMap
Dim lLayer As IFeatureLayer
Set lLayer = mMap.Layer(0)
Dim pActiveView As IActiveView
Set pActiveView = mMap

'variable d'objet pour la couleur de selection
Dim sColor As IColor
Set sColor = New RgbColor
sColor.RGB = RGB(140, 255, 122)

Dim qQuery As IQueryFilter
Dim sSelection As IFeatureSelection
'prepare a query filter
Set qQuery = New QueryFilter
qQuery.WhereClause = "years<=" & UserForm.Slider1.Value & ""
'refresh the old selection
pActiveView.PartialRefresh esriViewGeoSelection, Nothing, Nothing
'select feautures
Set sSelection = lLayer

sSelection.SelectFeatures qQuery, esriSelectionResultNew, False

'couleur de selection
sSelection.SelectionColor.RGB

'refresh
pActiveView.PartialRefresh esriViewGeoSelection, Nothing, Nothing
--------------------------------------------------------------------------------------

Merci deja.
A+

Tnarbiv · Wed 11 June 2008 13:09

bonjour,

1
si tu es en 9.1 voici le modèle objet http://edndoc.esri.com/arcobjects/9.1/A … opOMDs.pdf
Normalement quand tu installes arcgis tu peux si tu veux installer le developer kit et à ce moment là tu as un répertoire qui se créé C:\Program Files\ArcGIS\DeveloperKit\Diagrams dans lequel tu dois pouvoir trouver un modèle objet AllDesktopOMDs.pdf

2
peux tu utiliser le deboggeur pour voir où ça plante réellement.
peux tu également vérifier ta conditon qQuery.WhereClause = "years<=" & UserForm.Slider1.Value & ""

Tnarbiv · Wed 11 June 2008 13:17

la propriété SelectionColor est affectée par référence
en gros tu dois utiliser le mot clé Set devant la ligne

'couleur de selection
Set sSelection.SelectionColor.RGB

peux tu essayer ceci :
sSelection.SetSelectionSymbol = FALSE
Set sSelection.SelectionColor = sColor.RGB

calito · Wed 11 June 2008 14:15

J'ai essayé, ca'n marche pas

premierement j'ai declaré ma variable d'objet
Dim sColor As IColor
Set sColor = New RgbColor
sColor.RGB = RGB(140, 255, 122)

deuxiement, j'ai ajouter ce que tu m'avais dit:
sSelection.SetSelectionSymbol = False
Set sSelection.SelectionColor.RGB = sColor.RGB

Toujour la meme erreur: invalid use property(en selectionnant RGB)

Tnarbiv · Wed 11 June 2008 15:24

peux tu essayer ça
le fichier sur lequel je travaille est stocké au sein d'une géodatabase et ça marche alors que si le fichier est un fichier de forme cela ne marche pas

Code:

Public Sub SelectMapFeaturesAndRefresh()
    Dim pMxDoc As IMxDocument
    Dim pMap As IMap
    Dim pActiveView As IActiveView
    Dim pFeatureLayer As IFeatureLayer
    Dim pFeatureSelection As IFeatureSelection
    Dim pQueryFilter As IQueryFilter
    
    Set pMxDoc = ThisDocument
    Set pMap = pMxDoc.FocusMap
    Set pActiveView = pMap
    
    'For simplicity sake let's use the first layer in the map
    If Not TypeOf pMap.Layer(0) Is IFeatureLayer Then Exit Sub
    
    Set pFeatureLayer = pMap.Layer(0)
    Set pFeatureSelection = pFeatureLayer 'QI
    
    'Create the query filter
    Set pQueryFilter = New QueryFilter

    pQueryFilter.WhereClause = "years<=" & UserForm.Slider1.Value & ""
    
    'Invalidate only the selection cache
    'Flag the original selection
    pActiveView.PartialRefresh esriViewGeoSelection, Nothing, Nothing

    Dim pColor As IColor
    Set pColor = New RgbColor
    pColor.RGB = RGB(140, 255, 122)
    Set pFeatureSelection.SelectionColor = pColor
    
    'Perform the selection
    pFeatureSelection.SelectFeatures pQueryFilter, esriSelectionResultNew, False
    
    'Flag the new selection
    pActiveView.PartialRefresh esriViewGeoSelection, Nothing, Nothing
    
End Sub

Dernière modification par Tnarbiv (Wed 11 June 2008 15:24)

calito · Wed 11 June 2008 23:23

j'utilise un fichier de forme. Il n'est pas stocké dans une geodatabase.

calito · Wed 11 June 2008 23:39

Oui, je viens de le faire lorsque j'utilise une geodatabase mais, je voulais le faire sans utiliser une geodatabase.

calito · Wed 11 June 2008 23:47

OKEY OKEY, c'est bon maintenant, je viens de le faire sans intégrer le fichier de forme dans une géodatabase.

Merci infiniment.

Tnarbiv · Thu 12 June 2008 09:01

peux tu nous dire comment tu as fait ?

calito · Thu 12 June 2008 13:23

J'ai fait ce que vous m'aviez dit, mais je n'ai pas utiliser de geodatabase. J'ai ajouter une couche, et sur cette couche j'ai appliqué ma requête.
Lorsque je suis sur Windows XP, ça'n fonctionne pas, mais avec Vista ça marche
voici les codes:

Code:

Private Sub CommandButton1_Click()

Dim Doc As IMxDocument
Set Doc = ThisDocument
Dim mMap As IMap
Set mMap = Doc.FocusMap
Dim lLayer As IFeatureLayer
Set lLayer = mMap.Layer(0)
Dim pActiveView As IActiveView
Set pActiveView = mMap

Dim qQuery As IQueryFilter
Dim sSelection As IFeatureSelection

Set qQuery = New QueryFilter
qQuery.WhereClause = "Population<=100000"
    

Set sSelection = lLayer

    Dim pColor As IColor
    Set pColor = New RgbColor
    pColor.RGB = RGB(255, 10, 10)
    Set sSelection.SelectionColor = pColor

sSelection.SelectFeatures qQuery, esriSelectionResultAdd, False

pActiveView.PartialRefresh esriViewGeoSelection, Nothing, Nothing


End Sub

Je voulais l'utiliser dans une boucle. A chaque lecture d'un champ je vois que les entités selectionés avant clignote. Je crois que c'est à cause du "RFRESH". Comment je peut eviter le raffraichissement de la carte apres chaque requete?

Dernière modification par calito (Thu 12 June 2008 13:30)

Communauté	Ressources	L'emploi	Le marché	L'association	Fils RSS
Forum Blogs Wiki Planet Sites amis	Agenda Biblio Fiches AMO-CNIG Paris PCGIS Téléchargements	Offres d'emploi Banque de CV Formations Démarche Métiers	Geo-Entreprises Geo-Communiqué Appels d'offres	L'association Qui sommes-nous ? Nous aider Bienfaiteurs Partenaires Historique Statuts	Tout le site Job Géomatique Services GeoBlogs ...	Faire un don Mentions légales

Le portail francophone de la géomatique

Annonce

#1 Mon 09 June 2008 23:58

programmation ArcObjet avec VBA

#2 Tue 10 June 2008 09:05

Re: programmation ArcObjet avec VBA

Code:

#3 Wed 11 June 2008 12:11

Re: programmation ArcObjet avec VBA

#4 Wed 11 June 2008 13:09

Re: programmation ArcObjet avec VBA

#5 Wed 11 June 2008 13:17

Re: programmation ArcObjet avec VBA

#6 Wed 11 June 2008 14:15

Re: programmation ArcObjet avec VBA

#7 Wed 11 June 2008 15:24

Re: programmation ArcObjet avec VBA

Code:

#8 Wed 11 June 2008 23:23

Re: programmation ArcObjet avec VBA

#9 Wed 11 June 2008 23:39

Re: programmation ArcObjet avec VBA

#10 Wed 11 June 2008 23:47

Re: programmation ArcObjet avec VBA

#11 Thu 12 June 2008 09:01

Re: programmation ArcObjet avec VBA

#12 Thu 12 June 2008 13:23

Re: programmation ArcObjet avec VBA

Code:

Pied de page des forums