Nous utilisons des cookies pour vous garantir la meilleure expérience sur notre site. Si vous continuez à utiliser ce dernier, nous considèrerons que vous acceptez l'utilisation des cookies. J'ai compris ! ou En savoir plus !.
banniere

Le portail francophone de la géomatique


Toujours pas inscrit ? Mot de passe oublié ?
Nom d'utilisateur    Mot de passe              Toujours pas inscrit ?   Mot de passe oublié ?

Annonce

Pour sécuriser votre compte sur les forums du GeoRezo, nous demandons de changer votre mot de passe.

Vous allez recevoir un message pour effectuer ce changement de mot de passe.

Merci de bien respecter les règles préconisées.

#1 Sun 25 October 2009 17:19

fredericfridi
Participant actif
Date d'inscription: 2 Feb 2008
Messages: 97

Mapbasic Remplir Un Champ Type

Bonjour

je dessine en mapbasic des lignes avec la commande:

Code:

Run Menu Command 1713

Update Projet_connexe Set Type = 125

Avec la premiere ligne de code je dessine bien une polyligne
mais si j'ajoute la deuxieme ligne de code
je n ai pas la possibilité de dessiner.

moi ce que je shouaite c'est dessiner une polyligne
une fois que j'ai fait echap mettre à jour le champ type avec 125 ou 130

Merci

Dernière modification par fredericfridi (Sun 25 October 2009 22:01)

Hors ligne

 

#2 Tue 27 October 2009 08:20

fredericfridi
Participant actif
Date d'inscription: 2 Feb 2008
Messages: 97

Re: Mapbasic Remplir Un Champ Type

Bonjour
Réponse de moi même

je pense qu il faut écrire dans la table :  "125"  dans le champ Type,
selectionner le dernier enregistrement
puis dessiner la Ligne.

Juste comment fait on pour selectionner le dernier enregistrement dans une table en Mapbasic?

Merci

Dernière modification par fredericfridi (Tue 27 October 2009 08:21)

Hors ligne

 

#3 Tue 27 October 2009 14:34

Richard Lohier
Participant occasionnel
Lieu: Le perray en yvelines
Date d'inscription: 13 Nov 2006
Messages: 28

Re: Mapbasic Remplir Un Champ Type

Bonjour,

Ci après un exemple de code qui devrait répondre à vos questions...

Code:

Include "MAPBASIC.DEF"
Include "icons.DEF"

Declare Sub Main
Declare Sub Saisie
Declare Sub Saisie_Dialog

Dim TableCible$ as String
Dim TableCible@ as Alias
Dim Colonne1# as Integer
Dim NomColonne$ as String

Sub Main
' Définition de la table cible, et de la colonne à mettre à jour
    TableCible$ = "France_departements"
    TableCible@ = TableCible$
    NomColonne$ = "col1"

    Create ButtonPad "Saisie" As 
        ToolButton 
            HelpMsg "Utilisez cet outil pour tracer une ligne." 
            Calling Saisie 
            Icon MI_ICON_CROSSHAIR 
            DrawMode DM_CUSTOM_POLYLINE     
        Title "Saisie"
        Width 3
        Show 
End Sub

Sub Saisie
    Dim Objet£ as Object
    Dim NombreLignes# as integer
' Récupération de l'objet saisie
    Objet£ = CommandInfo(CMD_INFO_CUSTOM_OBJ)
' Appel de la boite de dialogue de choix de valeur
    Call Saisie_Dialog

    If Colonne1# <> 0 Then 
        Insert into TableCible$ (NomColonne$,obj) 
            Values (Colonne1#, Objet£)
' Sélection de la dernière ligne de la table
        SelecNombreLignes# = TableInfo(TableCible$, TAB_INFO_NROWS)

        Select * From TableCible@ 
            Where Rowid = NombreLignes# 
            Into Selection
    End If
End Sub

Sub Saisie_Dialog
    Dim ChoixValeur# as integer

    Dialog
        Title "Informations" 
        Control StaticText
            Title "Valeur de la colonne 1:" 
'        Control EditText 
'            Value Colonne1# 
'            Into Colonne1#
        Control Listbox
            Id 968
            Title "125;130"
            Value ChoixValeur# 
            Into ChoixValeur#
        Control OKButton
        Control CancelButton 

    If CommandInfo(CMD_INFO_DLG_OK) Then 
         Do Case ChoixValeur# 
            Case 1
                Colonne1# = 125
            Case 2 
                Colonne1# = 130
            Case Else
                Colonne1# = 0
        End Case
    End If
End Sub

Hors ligne

 

Pied de page des forums

Powered by FluxBB