Le portail francophone de la géomatique

Hello

Non malheureusement Autodesk ne fournit aucune possibilite simple d'extraire les donnees d'objet (Object Data) de MAP (ou CIVIL) 
AUTRE que faire une requete en mode "Rapport" sur le/les dessin(s) actif(s) du groupe de dessins de MAP (ou CIVIL) !

Sniff, sniff, GeoBye, Pat

Bonjour,

Voila qui redonne le sourire.

J'étais au bord des larmes après la réponse de Patrice.

Q'uen pense t-il d'ailleurs?

Le fait de pouvoir récupérer ces données sous access me va très bien.
On peut toujours faire une Query sous excel pour lire les données.

Par ailleurs, s'il était possible de générer des liens directement des objets eux mêmes vers access,
ce serait le TOP!

Merci pour tout

re bonjour

je confirme , la fonction "convertir des données d'objet en liens de base de données " crée non seulement la base access à partir des données d'objet ( une table à la fois) mais elle crée bien un lien entre  la base et l'objet .

Hello

Un MAPEXPORT au format SHP est correct et en effet on obtient toutes les Infos attributaires dans le DBF (le graphique etant dans le SHP)

Mais on peut faire aussi un MAPEXPORT au format MIF-MID et le fameux fichier MID (fichier texte) ne contient que les donnees attributaires en texte ce qui est parfois aussi interessant !

Convertir les donnees d'objets de MAP en lien ASE (Commande: _MAPOD2ASE) est aussi valable mais c un peu plus subtil !
mais je crains que cela ne soit pas possible sur un Win 64 bits (XP PRO, Vista, Seven) avec un AutoCAD MAP (ou CIVIL) 64 bits

Quoique peut etre que avec un Office 2010 64 bits, il soit peut etre possible de realiser cette bonne vieille manipulation mais bon je n'ai pas sous la main la config necessaire ... Donc si jamais qq'un peut repondre cela serait sympa !?

GeoBye, Pat

Bonjour,

J'ai testé avec Map 3D 2012 en x64 sur Seven x64, et cela fonctionne.

Tout à fait, c'est bien une condition, comme sur ce thread..

Cordialement,
Gwenael

Bonjour,

Pour ceux qui voudrait passer par un CSV lisible sous Excel, je peux vous proposer ce qui suit:

(defun c:OD2CSV ( / js dxf_cod mod_sel n lremov file_name cle f_open key_sep str_sep oldim lst_tabl_def lst_def l_tag l_tod l_val)
  (princ "\nChoix d'un objet modèle pour le filtrage: ")
  (while
    (null
      (setq js
        (ssget "_+.:E:S"
          (list
            '(0 . "*")
            (cons 67 (if (eq (getvar "CVPORT") 1) 1 0))
            (cons 410 (if (eq (getvar "CVPORT") 1) (getvar "CTAB") "Model"))
          )
        )
      )
    )
    (princ "\nCe n'est pas un objet valable pour cette fonction!")
  )
  (vl-load-com)
  (setq dxf_cod (entget (ssname js 0)))
  (foreach m (foreach n dxf_cod (if (not (member (car n) '(0 67 410 8 6 62 48 420 70))) (setq lremov (cons (car n) lremov))))
    (setq dxf_cod (vl-remove (assoc m dxf_cod) dxf_cod))
  )
  (initget "Unique Tout Manuel _Single All Manual")
  (if (eq (setq mod_sel (getkword "\nMode de sélection filtrée, choix [Unique/Tout/Manuel]<Manuel>: ")) "Single")
    (setq n -1)
    (if (eq mod_sel "All")
        (setq js (ssget "_X" dxf_cod) n -1)
        (setq js (ssget dxf_cod) n -1)
    )
  )
  (setq file_name (getfiled "Nom du fichier a créer ?: " (strcat (substr (getvar "dwgname") 1 (- (strlen (getvar "dwgname")) 3)) "csv") "csv" 37))
  (if (null file_name) (exit))
  (if (findfile file_name)
    (progn
      (prompt "\nFichier éxiste déjà!")
      (initget "Ajoute Remplace annUler _Add Replace Undo")
      (setq cle
        (getkword "\nDonnées dans fichier? [Ajouter/Remplacer/annUler] <R>: ")
      )
      (cond
        ((eq cle "Add")
          (setq cle "a")
        )
        ((or (eq cle "Replace") (eq cle ()))
          (setq cle "w")
        )
        (T (exit))
      )
      (setq f_open (open file_name cle))
    )
    (setq f_open (open file_name "w"))
  )
  (initget "Espace Virgule Point-virgule Tabulation _SPace Comma SEmicolon Tabulation")
  (setq key_sep (getkword "\nSéparateur [Espace/Virgule/Point-virgule/Tabulation]? <Point-virgule>: "))
  (cond
    ((eq key_sep "SPpace") (setq str_sep " "))
    ((eq key_sep "Comma") (setq str_sep ","))
    ((eq key_sep "Tabulation") (setq str_sep "\t"))
    (T (setq str_sep ";"))
  )
  (setq oldim (getvar "dimzin"))
  (setvar "dimzin" 0)
  (repeat (sslength js)
    (setq lst_def nil l_tag nil l_tod nil l_val nil)
    (if (setq lst_tabl_def (mapcar 'ade_odtabledefn (ade_odgettables (setq ename (ssname js (setq n (1+ n)))))))
      (foreach n lst_tabl_def
        (foreach el n
          (if (listp (cdr el))
            (foreach sel (cdr el)
              (foreach msel sel
                (if (eq (car msel) "ColName")
                  (setq lst_def (cons (cdr msel) (cons (ade_odgetfield ename (cdar n) (cdr msel) 0) lst_def)))
                  (if (eq (car msel) "ColDesc") (setq lst_def (cons (cdr msel) lst_def)))
                )
              )
            )
          )
          (while lst_def
            (repeat 3
              (setq
                l_tag (cons (car lst_def) l_tag)
                l_tod (cons (cadr lst_def) l_tod)
                l_val (cons (caddr lst_def) l_val)
                lst_def (cdddr lst_def)
              )
            )
          )
          (if (and l_tag l_tod l_val)
            (progn
              (write-line (apply 'strcat (mapcar '(lambda (x) (strcat x str_sep)) l_tag)) f_open)
              (write-line (apply 'strcat (mapcar '(lambda (x) (strcat x str_sep)) l_tod)) f_open)
              (write-line (apply 'strcat (mapcar '(lambda (x) (strcat (cond ((eq (type x) 'INT) (itoa x)) ((eq (type x) 'REAL) (rtos x 2)) (T x)) str_sep)) l_val)) f_open)
              (setq l_tag nil l_tod nil l_val nil)
            )
          )
        )
      )
    )
  )
  (close f_open)
  (setvar "dimzin" oldim)
  (prin1)
)

Salut Patrice,

Je n'ai pas ce problème avec Map2009 & Covadis sous Xp 32.

Tout ce que que je peux te suggérer (puisque que tu veux une virgule comme séparateur) et de remplacer dans le code:

  (initget "Espace Virgule Point-virgule Tabulation _SPace Comma SEmicolon Tabulation")
  (setq key_sep (getkword "\nSéparateur [Espace/Virgule/Point-virgule/Tabulation]? <Point-virgule>: "))
  (cond
    ((eq key_sep "SPpace") (setq str_sep " "))
    ((eq key_sep "Comma") (setq str_sep ","))
    ((eq key_sep "Tabulation") (setq str_sep "\t"))
    (T (setq str_sep ";"))
  )

Par simplement

  (setq str_sep ",")

et de refaire l'essai.
Autrement il faudrait voir si d'autres personnes ont le même problème avec des versions supérieur à 2009 sous 32 ou 64.

Tu peux déjà tester à part le code que je t'ai fait enlever, et me dire ce que contiennent les variables "key_sep" et "str_sep" après exécution...

Le problème ne vient pas à priori du DWG, ni du copier/coller (J'ai testé directement depuis le site en collant directement en ligne de commande)

Je veux bien attacher le fichier (séparateur fixé à la ","), mais je doute du résultat...

Tu n'as pas à être désolé, j'aurais du envisager ces cas de figures pour un code plus fiable (champs non-renseignés).

J'espère que celui-ci sera plus robuste, ton DWG de test m'a bien aidé pour cette tache.

NB: J'ai rajouté une remarque dans le code (à regarder). En effet si les entités ont plusieurs applications d'OD attachées (j'ai fait le test) on ne sait plus dans le CSV à quoi sont rattachées les données.

Dernière modification par bruno v. (Wed 06 April 2011 17:04)

Ravi que ça fonctionne !

Je pense que c'est faisable à priori, le problème et que je ne peux faire du développement avec Map (et quelque tests compris) qu'au boulot, donc c'est seulement pendant des périodes peu chargées.

Demain, quinze jours, un mois .... ?

Bonjour,

Merci M. Bruno V.
Avant toute chose, très beau travail que vous avez fait là.

Sur un AutoCAD MAP 2009, j'ai testé la routine OD&PROP2CSV.lsp, la case de dialogue fonctionne, l'export aussi.

En lisant sur un éditeur Notepad++ (juste pour contrôler le csv généré qui se trouve en pièce-jointe) je me suis aperçu qu'en ayant coché Longueur de l'objet, le résultat donne la valeur 0.00 alors que mes données sont issues de lwpolylignes qui sont des filaires de voies et donc supérieur à 1 mètre.

Sinon, le nom de la table de données d'objets est décalée par rapport à la ligne correspondante.

Si l'export est prévu pour créer une base de données, je pense qu'il n'est pas nécessaire de répéter la ligne des champs à chaque enregistrement.
Une ligne de champs sur la première ligne est le minimum et le tour est joué.

Voilà et merci encore.

Fabcad,

Tout d'abord, merci du retour.

Exact, une mauvaise affectation de variable de ma part, j'ai mis le code à jour dans le post précédent.

Je l'ai bien observé sur ton CSV, mais je n'arrive pas à reproduire le même cas avec mes fichiers ayant des OD.

Comme j'ai pus le dire dans un post précédent:

Donc suivant l'utilisation que tu en as je te propose de mettre en REMarques (avec un ";" en début de ligne) les lignes signalées dans le code.

Ça rejoint la question précédente, c'est faisable pour le cas que tu cites, mais je ne désire pas le faire à cause de la possibilité de plusieurs applications d'OD sur le même objet. Donc dans l'état, c'est tout ou rien suivant la mise en REMarque des lignes de codes.

Dernière modification par bruno v. (Thu 14 April 2011 16:07)

Merci Bruno pour les informations complémentaires, vraiment efficace pour créer des listings.

Bonne journée,

A+

On peut le faire, mais je me vois mal écrire un truc générique qui pourrait fonctionner pour tout le monde.
Seule solution mettre les mains dans le cambouis.

Je veux bien donner les fichiers qui m'ont servi à constituer ma base, cela peut être un point de départ pour ceux qui le veulent, à faire leur propre adaptation.

Ma problématique était que j'avais récupéré le fichier en XLS de l'INSEE concernant la population de mon département (339 communes).
J'ai donc commencé par mettre le fichier de la population  en CSV
J'ai lancé mon lisp et il a fallu que je désigne (pour la 1ere fois, je n'avais pas d'autre moyen à moins de faire un lisp compliqué, en sachant que cette procédure n'allait me servir qu'une seule fois...) un à un les MPOLYGON concernés.

J'ai trouvé par la suite d'autre données INSEE que j'ai voulu compléter aux OD existantes
J'ai donc construit un lisp qui m'a permis de compléter ma table en se servant déjà des données entrées pour identifier mes mpolygon.

En pièces jointes les fichiers qui m'ont servis...
Juste pour tester vous pouvez dessiner quelque MPOLYGON dans un dessin vierge (pas la peine d'en faire 339, vous ferez "Esc" dans la procédure)
Lancez le lisp population2od.lsp en AYANT ADAPTE LE CHEMIN DU CSV dans celui-ci
Idem pour le fichier read_fiel-map.lsp

Si ces codes m'ont pris une journée ou deux d'écriture et de mise au point, ils m'ont épargné une saisie longue et très fastidieuse.
Voilà pour ceux qui se sentent d'attaque à plonger dans l'adaptation. (Ca peu sembler hard, mais que de temps gagné pour aller sur les forums) :p

Bonjour.
S'il s'agit d'extraire les données d'objet d'un fichier DWG avec AutoCad MAP, il y a possibilité d'associer une source de données, par exemple un fichier Excel, par l'explorateur de carte, par un clic droit sur "Sources de données".
Autocad Map va créer lui même la source de données ODBC. Ensuite, avec la commande MAPOD2ASE, il est possible de convertir les données d'objet vers la source de données (ici un fichier Excel), et de faire un lien automatique entre les objets du dessin et les enregistrements de la source de données. Tout cela marche bien.
Seul bémol : je ne parviens pas à ouvrir la table, sous AutocadMap, en mode modification, mais uniquement en lecture seule.
Pourtant, en vérifiant la config de ma source de données ODBC (créée par AcadMap) par le panneau de configuration, la case à cocher lecture seule est bien décochée. De plus, en vérifiant sous AutocadMap, cette fois, les "Propriétés des liaisons de données", j'ai coché dans les autorisations d'accès "ReadWrite".

Quelqu'un saurait-il comment ouvrir en modification une table de données liées (via une source de données ODBC) à un dessin DWG ?

Merci d'avance. Cordialement, Alexis GAILLOT