Le portail francophone de la géomatique

Voici un exemple de code VB qui découpe une classe raster stockée dans une geodatabase ArcSDE vers une classe raster stockée dans une geodatabase personnelle (en fait un fichier .img). Le découpage est effectué en précisant les coordonnées terrain du rectangle de découpage. On pourrait, pour améliorer le code aller chercher l'enveloppe d'une entité d'une classe d'entités ou d'un shapefile servant de source de découpage

Bon codage,

Private Sub ClipRaster()

Dim pRasterProp As esriDataSourcesRaster.IRasterProps

Dim pBands As esriDataSourcesRaster.IRasterBandCollection

Dim pBand As esriDataSourcesRaster.IRasterBand

Dim pRaster As esriGeoDatabase.IRaster

Dim pRasterDS As esriGeoDatabase.IRasterDataset



Dim pSDEFact As esriGeoDatabase.IWorkspaceFactory

Dim pAccessWksFact As esriGeoDatabase.IWorkspaceFactory



Dim pPropset As esriSystem.IPropertySet

Dim pWks As esriGeoDatabase.IWorkspace



Dim pSigDONRas As esriGeoDatabase.IRasterWorkspaceEx

Dim pClipRas As esriGeoDatabase.IRasterWorkspaceEx



Dim pExt As esriGeometry.IEnvelope



Dim dTailleCell As Double



Dim iCol As Integer

Dim iRow As Integer

Dim sName As String

Dim sNewPath As String



' *********************************************************************************

' * Connexion à la géodatabase personnelle qui accueille le résultat du découpage *

' *********************************************************************************

Set pAccessWksFact = New esriDataSourcesGDB.AccessWorkspaceFactory

Set pClipRas = pAccessWksFact.OpenFromFile("C:\temp\clipraster.mdb", 0)

Set pAccessWksFact = Nothing



' *******************************************************************************

' * Connextion à la géodatabase ArcSDE qui contient la classe raster à découper *

' *******************************************************************************



Set pPropset = New esriSystem.PropertySet

With pPropset

  .SetProperty "SERVER", "NOM_DU_SERVEUR_ARCSDE"

  .SetProperty "INSTANCE", "NOM_SERVICE_OU_PORT_TCP"

  .SetProperty "DATABASE", ""

  .SetProperty "USER", "UTILISATEUR_AUTORISE"

  .SetProperty "PASSWORD", "MOT_DE_PASSE"

  .SetProperty "VERSION", "SDE.DEFAULT_OU_AUTRE_VERSION"

End With



Set pSDEFact = New esriDataSourcesGDB.SdeWorkspaceFactory

Set pSigDONRas = pSDEFact.Open(pPropset, 0)

Set pPropset = Nothing

Set pSDEFact = Nothing



' **********************************************

' * Pointer sur la classe raster à découper    *

' * et initialiser l'objet cible du découpage. *

' **********************************************

Set pRasterDS = pSigDONRas.OpenRasterDataset("NOM_DE_LA_CLASSE_RASTER_A_DECOUPER")



Set pRaster = pRasterDS.CreateDefaultRaster

Set pRasterProp = pRaster

Set pBands = pRaster



' *********************************************

' * Définir le rectangle de découpage.        *

' * Dans l'exemple, on est en mètres terrain. *

' *********************************************



Set pExt = New esriGeometry.Envelope

With pExt

    .XMin = 361951

    .YMin = 2352451

    .XMax = 501128

    .YMax = 2445172

End With



' ************************************************************

' * Affecter les hauteur et largeur en pixel en fonction     *

' * de la taille de la cellule. Attention, ici la résolution *

' * est la même en X qu'en Y.                         *

' * Affecter l'etendue spatiale.                     *

' ************************************************************



With pRasterProp

    dTailleCell = (.MeanCellSize.X + .MeanCellSize.Y) / 2

    .Width = Int((pExt.XMax - pExt.XMin) / dTailleCell)

    .Height = Int((pExt.YMax - pExt.YMin) / dTailleCell)



    .Extent = pExt

End With



' ***********************************************************

' * Effectuer le découpage dans la géodatabase personnelle. *

' ***********************************************************



pBands.SaveAs "NOM_DE_LA_CLASSE_RASTER_DECOUPEE", pClipRas, "TIFF"



' ***********************

' * Détruire les objets *

' ***********************



Set pRasterDS = Nothing

Set pRaster = Nothing

Set pExt = Nothing

Set pRasterProp = Nothing

Set pBands = Nothing

Set pRasterDS = Nothing

set pClipRas = nothing

Set pSigDONRas = Nothing

End Sub

yvan.

Si vous souhaitez vous en assurer, changer l'espace de stockage pour un système de fichiers plutôt qu'une geodatabase personnelle comme dans mon exemple et essayez. Si le fichier world (.tfw) n'est pas généré, vous pouvez utiliser l'interface esriDataSourcesRaster::IworldFileExport comme ci-après :

Dim pWorldFileExport as esriDataSourcesRaster.IWorldFileExport

'  Faire pointer sur le jeu de données Raster découpé
Set pWorldFileExport = pRasterDS
pWorldFileExport.Write

set pWorldFileExport = Nothing

bon courage,

yvan.

Une classe raster stocke des données raster dans une geodatabase ArcSDE.

C'est, pardonnez-moi le raccourci, l'équivalent d'un fichier TIFF (ou autre type) mais hébergé par une geodatabase ArcSDE.

Si vos images sont rassemblées au sein d'un répertoire, il va falloir les mosaïquer (arctoolbox propose si mes souvenirs sont bons un tel outil) avant d'effectuer le découpage, à moins que ce dernier ne soit possible à partir d'un catalogue d'images d'une géodatabase ArcSDE (renseignez-vous auprès de l'équipe d'ESRI France).

bon courage,

yvan.

Bonjour

Je relance cette discussion qui m'a énormément servie car je n'arrive pas à récupérer le fichier de géoréférencement .tfw

Le raster en sortie se trouve dans un répertoire et le clip défini se réalise sans problème.
J'essaye d'utiliser l'objet "IWorldFileExport" comme il est conseillé mais je ne vois pas de résultat.
Pourtant il n'y a pas de bug sur cette cet objet ni quand je lance sa fonction Write.

Si quelqu'un peut m'éclairer sur ce sujet, je l'en remercie d'avance.

Juuuules

C'est bon ça marche, j'oubliais juste de redéfinir le RasterDs.

Par contre j'ai un autre problème, l'apparence de l'image découpée, une fois chargée dans ArcMap, diffère quelque peu de l'original( au niveau de la teinte).
Par contre, si je l'ai compare sur un viewer d'image (en l'occurence XnView) il n'y a aucune différence.
ça doit pas être si grave.. enfin j'espère...

Sinon, vu que mes découpages seront souvent à effectuer sur plusieurs rasters concommitants, je pense ne pas pouvoir éviter l'étape du mosaïquage.
J'ai commencé à programmer la-dessus mais c'est pas fameux, j'obtiens un image toute noire.

Si vous avez quelques tuyaux à ce sujet....

Juuuules

svp j ai essayé un exemple donnée par le help de arcgis developper concernant clip raster, mais lorsque j'ai essayer de le compiler il me signe qu'il y unje variable indefinié j ai essayer avec un autre exemple il me signe le meme erreur disant qu il y une variable non definie
svp si qlq peut m'aider pour savoir compiler les exemples

Dernière modification par jamasig (Thu 27 July 2006 19:45)

J'ai fais les tests de mosaïquage vers un nouveau raster et je rencontre encore un problème. Vu que je suis contraint de renseigner une taille de pixel identique à celle de mes images d'origine (cad 0.5), j'obtiens comme résultat une image agrandie. Il n'y a plus aucun respect de l'échelle.

C'est en faisant des tests avec plusieurs tailles de pixel que je me suis rendu compte que cela venait de là.
En effet, dès que je mets une taille de pixel inférieur à 1, il y a automatiquement agrandissement de l'image.
J'ai tenté un redimensionnement mais l'image n'est plus bien géoréférencée.

De plus, ce que je veux c'est lancer mon mosaïquage dans une routine par programmation. Donc plutôt avec des objets du genre IMosaic....  Mais il se peut que l'on puisse appeler directement les outils d'arctoolbox sans faire apparaître la boite de dialogue.

Sinon, qu'est ce c'est que la boîte à outils complémentaires d'ESRI France? Je vais aller voir sur le support...

Juuuules

La boite outil complementaire d'ESRI se telecharge gratuitement sur le site du support d'ESRI.

Description:

La boîte d'outils complémentaires ESRI France contient un ensemble d'outils de géotraitement accessibles à partir de la fenêtre ArcToolBox.
Régulièrement complétée par nos soins, elle a pour principal objectif d'illustrer les possibilités de personnalisation de l'environnement de géotraitement d'ArcGIS 9 (scripts, modèles, ...) tout en essayant de répondre à vos besoins les plus fréquents.

Dernière modification par Miniopterine (Wed 08 August 2007 22:33)