Le portail francophone de la géomatique

Bonjour,

Je ne travaille pas sur AutoCAD MAP mais sur AutoCAD (2013) et je pense que la manip est identique,
pour ma part je procède de la sorte :
dans chaque présentation, je sélectionne le cadre (pas la fenêtre mais un cadre exactement comme la fenêtre et positionné au même endroit),
ensuite je tape "chspace" (pour changer d'espace), et la fenêtre s'active pour pouvoir changer d'espace et il suffit de faire "entrée" : c'est à dire que l'objet sélectionne va se positionner dans l'espace objet exactement au bon endroit à la bonne échelle et bien sur il disparait de l'espace papier (donc si un polygone délimite ta fenêtre, copie le avant)

Tu répètes ça pour tes 50 présentations (ça va vite) et tu te retrouves avec un calepinage sur ton funiculaire avec les planches de présentations,
tu mets toutes tes planches dans un calque à part que tu peux désactiver dans les présentations, tu fais une petite fenêtre en plus dans chaque présentation avec ce calepinage et le projet si tu veux le faire apparaître, à une échelle qui convienne genre 25000;
sinon tu peux aussi déplacer ces objets dans un coin vide du dessin et les réduire, en faire un bloc que tu copies, en ayant numéroté tes planches avant.... il y a plusieurs possibilités mais pour ma part, je prépare le calepinage avant de faire mes présentations, dans l'espace objet, et ensuite je "cale" mes présentations sur chaque planche,

Voilà, si c'est bien ce que tu voulais !

Rien d'automatique à ma connaissance, on n'est pas sur Arcview ! qui fait tout seul avec les pages dynamiques et l'indicateur d'emprise !
bonne journée

Capture en fichier joint
Les fenêtres (FMULT) existent déjà dans une cinquantaine de présentation (une fenêtre FMULT par presentation).
Je voudrais générer automatiquement des encadrements dans l'objet. Chaque encadrement représente l'emprise d'une fenêtre (FMULT) d'une présentation.
Si possible avec le nom de la présentation dans un coin de l'encadrement.

Je pensé que ce serait une fonction Basic

Dernière modification par cmoi2025 (Wed 26 October 2016 16:06)

Si c'est la méthodologie décrite que tu réalise, on peux faire une sorte de script en lisp pour réaliser cela.
La procédure une fois lancée peut être un peu longue (surtout pour 50 présentation), Autocad peut même signaler dans le titre de la fenêtre qu'il ne réponds pas, mais laisser faire quand même, il finira par rendre la main...

Cela ne traite que les fenêtres simples (j'ai pas testé de fenêtre polygonale), et met un texte rappelant le nom de la présentation.

(defun c:test ( / el js n ent dxf_ent pt_v l h lst_pt js_obj)
  (vl-load-com)
  (foreach el (layoutlist)
    (setvar "CTAB" el)
    (setq js
      (ssget "_X"
        (list
          '(0 . "VIEWPORT")
          '(67 . 1)
          (cons 410 el)
          '(-4 . "!=")
          '(69 . 1)
        )
      )
    )
    (repeat (setq n (sslength js))
      (setq
        js_obj nil
        pt_v (cdr (assoc 10 (setq dxf_ent (entget (setq ent (ssname js (setq n (1- n))))))))
        l (cdr (assoc 40 dxf_ent))
        h (cdr (assoc 41 dxf_ent))
        lst_pt
        (list
          (list (- (car pt_v) (* 0.5 l)) (- (cadr pt_v) (* 0.5 h)) 0.0)
          (list (+ (car pt_v) (* 0.5 l)) (- (cadr pt_v) (* 0.5 h)) 0.0)
          (list (+ (car pt_v) (* 0.5 l)) (+ (cadr pt_v) (* 0.5 h)) 0.0)
          (list (- (car pt_v) (* 0.5 l)) (+ (cadr pt_v) (* 0.5 h)) 0.0)
        )
        js_obj (ssadd)
      )
      (entmakex
        (vl-list*
          (cons 0 "LWPOLYLINE")
          (cons 100 "AcDbEntity")
          (cons 67 1)
          (cons 100 "AcDbPolyline")
          (cons 90 (length lst_pt))
          (cons 70 1)
          (mapcar '(lambda (p) (cons 10 p)) lst_pt)
        )
      )
      (ssadd (entlast) js_obj)
      (entmake
        (list
          '(0 . "MTEXT")
          '(100 . "AcDbEntity")
          '(67 . 1)
          (cons 410 el)
          (cons 8 (getvar "CLAYER"))
          '(100 . "AcDbMText")
          (cons 10 (car lst_pt))
          '(40 . 3.5)
          '(41 . 0.0)
          '(46 . 0.0)
          '(71 . 7)
          '(72 . 5)
          (cons 1 (strcat "{\\fArial|b0|i0|c0|p34;" el))
          '(7 . "Standard")
          '(210 0.0 0.0 1.0)
          '(11 1.0 0.0 0.0)
          '(50 . 0.0)
          '(73 . 1)
          '(44 . 1.0)
        )
      )
      (ssadd (entlast) js_obj) 

(command "_.CHSPACE" js_obj "" (if (> (cdr (assoc 69 dxf_ent)) 2) "") ) 

    )
  )
  (prin1)
)

Dernière modification par bruno v. (Thu 27 October 2016 15:49)

Il faut dire que je n'ai pas fais d'essais très poussés...

Une erreur de variable de ma part et le filtre de ssget incomplet.
Je corrige le code ci-dessus.

Le lisp mis à jour fonctionne impeccable

Merci

Bonjour Bruno, quelle commande faut-il rentrer pour exécuter le Lisp une fois chargée dans AutoCAD ?
"test" ne marche pas